home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Tech Arsenal 1
/
Tech Arsenal (Arsenal Computer).ISO
/
tek-05
/
maptdi.zip
/
MAIL.BAT
< prev
next >
Wrap
DOS Batch File
|
1991-11-21
|
2KB
|
41 lines
@ECHO off
REM
REM This .BAT file runs Consumer Software's Network Courier E-Mail product,
REM since gobbled up by Microsoft to be offered under their own label.
REM
IF '%1'=='XC' GOTO Exchange_mail
ECHO:
ECHO Mail command for non-TSR programs.
ECHO:
REM
REM A call to the MapTDisk batchfile will place the letter for the next
REM available (unmapped) drive in the DOS environment variable "TempDisk".
REM If no drives are available for mapping, the variable will be set to "NONE"
REM
CALL MapTDisk RegLAN1/SYS:Courier\Data
IF "%TempDisk"=="NONE" GOTO NoCanDo
MAP INS S1:=RegLAN1/SYS:Courier\EXE
REM
REM If no argument is given, send the user into the mail program, if one (or
REM more) is present, assume that it's an executable like Admin or NewMail.
REM
IF '%1'=='' %TempDisk%:..\EXE\Mail -D%TempDisk%
IF NOT '%1'=='' %TempDisk%:..\EXE\%1 -D%TempDisk% %2 %3 %4 %5 %6 %7 %8 %9
MAP DEL S1:
CALL DelTDisk
GOTO End
:Exchange_mail
REM
REM On this LAN (RegLAN1), drives G: & H: are reserved for transient use --
REM no program should ever assume that they are mapped in any particular manner.
REM
MAP G:=RegLAN2/SYS:Appl\MailData > NUL
MAP H:=RegLAN1/SYS:Courier\Data >NUL
H:..\EXE\External -DGH -HH -A -SB -V %2 %3 %4 %5 %6 %7 %8 %9
MAP DEL G:
MAP DEL H:
GOTO End
:NoCanDo
SET TempDisk=
ECHO No mappable drives remaining!
:End